• Top
  • Documentation
  • Books
  • Boolean-reasoning
  • Projects
  • Debugging
  • Community
  • Std
  • Proof-automation
  • Macro-libraries
  • ACL2
  • Interfacing-tools
  • Hardware-verification
  • Software-verification
    • Kestrel-books
      • Crypto-hdwallet
      • Apt
      • Error-checking
      • Fty-extensions
      • Isar
      • Kestrel-utilities
      • Set
      • C
        • Syntax-for-tools
          • Formalized-subset
          • Mapping-to-language-definition
          • Input-files
          • Compilation-database
          • Printer
          • Output-files
          • Abstract-syntax-operations
          • Implementation-environments
          • Abstract-syntax
          • Concrete-syntax
          • Disambiguation
          • Validation
          • Gcc-builtins
          • Preprocessing
          • Parsing
            • Parser
              • Parse-exprs/decls/stmts
              • Parser-states
              • Parse-external-declaration
              • Parse-cast-expression
              • Parse-expression-or-type-name
              • Parse-postfix-expression
              • Lexer
              • Parse-primary-expression
              • Token-unary-expression-start-p
              • Parse-declaration-specifier
              • Parse-declaration-specifiers
              • Parse-unary-expression-or-parenthesized-type-name
              • Parse-asm-name-specifier
              • Parse-specifier/qualifier
              • Parse-expression-rest
              • Token-type-specifier-keyword-p
              • Parse-fileset
              • Parse-*-external-declaration
              • Parse-declarator-or-abstract-declarator
              • Parse-asm-goto-labels
              • Parse-asm-clobbers
              • Parse-translation-unit
              • Parse-*-label-declaration
              • Token-postfix-expression-rest-start-p
              • Parse-?-asm-name-specifier
              • Parse-*-comma-identifier
              • Parse-postfix-expression-rest
              • Parse-expression
              • Make-expr-unary-with-preinc/predec-ops
              • Parse-*-stringlit
              • Parse-statement
              • Token-struct-declaration-start-p
              • Parse-*-attribute-specifier
              • Parse-initializer-list
              • Parse-file
              • Parse-pointer
              • Parse-label-declaration
              • Parse-array/function-declarator
              • Token-type-qualifier-p
              • Parse-*-asm-qualifier
              • Parse-parameter-declaration
              • Parse-attribute-name
              • Parse-argument-expressions
              • Make-expr-cast/add-or-cast/sub-ambig
              • Parse-struct-or-union-specifier
              • Parse-declaration-or-statement
              • Parse-assignment-expression
              • Parse-asm-clobber
              • Token-specifier/qualifier-start-p
              • Token-primary-expression-start-p
              • Token-function-specifier-p
              • Token-expression-start-p
              • Parse-*-increment/decrement
              • Parse-direct-abstract-declarator
              • Parse-compound-statement
              • Token-to-type-specifier-keyword
              • Parse-unary-expression
              • Parse-argument-expressions-rest
              • Parse-generic-associations-rest
              • Parse-conditional-expression
              • Parse-fileset-loop
              • Parse-direct-abstract-declarator-rest
              • Token-designation?-initializer-start-p
              • Token-declaration-specifier-start-p
              • Parse-designator-list
              • Token-abstract-declarator-start-p
              • Parse-?-asm-output-operands
              • Parse-?-asm-input-operands
              • Parse-struct-declaration
              • Parse-specifier-qualifier-list
              • Parse-parameter-declaration-list
              • Parse-constant-expression
              • Token-type-specifier-start-p
              • Token-type-qualifier-or-attribute-specifier-start-p
              • Parse-static-assert-declaration
              • Parse-direct-declarator
              • Parse-declaration
              • Parse-attribute-parameters
              • Token-unary-operator-p
              • Token-to-unary-operator
              • Token-to-type-qualifier
              • Token-storage-class-specifier-p
              • Token-initializer-start-p
              • Token-direct-abstract-declarator-start-p
              • Token-declarator-start-p
              • Parse-initializer
              • Parse-direct-declarator-rest
              • Token-to-storage-class-specifier
              • Token-to-assignment-operator
              • Token-to-asm-qualifier
              • Token-struct-declarator-start-p
              • Token-direct-declarator-start-p
              • Token-assignment-operator-p
              • Parse-type-qualifier-and-attribute-specifier-list
              • Parse-enumerator-list
              • Parse-designation?-initializer
              • Parse-compound-literal
              • Parse-block-item
              • Token-type-name-start-p
              • Token-to-function-specifier
              • Token-preinc/predec-operator-p
              • Token-multiplicative-operator-p
              • Token-designator-start-p
              • Token-designation-start-p
              • Parse-generic-association
              • Parse-declaration-list
              • Parse-attribute-specifier
              • Parse-asm-output-operands
              • Token-to-relational-operator
              • Token-to-preinc/predec-operator
              • Token-to-multiplicative-operator
              • Token-relational-operator-p
              • Token-equality-operator-p
              • Token-asm-qualifier-p
              • Token-additive-operator-p
              • Parse-asm-statement
              • Parse-asm-input-operands
              • Token-to-equality-operator
              • Token-to-additive-operator
              • Token-shift-operator-p
              • Parser-messages
              • Parse-type-name
              • Parse-struct-declarator-list
              • Parse-struct-declaration-list
              • Parse-relational-expression-rest
              • Parse-multiplicative-expression-rest
              • Parse-logical-or-expression-rest
              • Parse-logical-and-expression-rest
              • Parse-inclusive-or-expression-rest
              • Parse-exclusive-or-expression-rest
              • Parse-equality-expression-rest
              • Parse-array/function-abstract-declarator
              • Parse-additive-expression-rest
              • Token-to-shift-operator
              • Parse-struct-declarator
              • Parse-shift-expression-rest
              • Parse-member-designor
              • Parse-init-declarator-list
              • Parse-init-declarator
              • Parse-designator
              • Parse-and-expression-rest
              • Parse-alignment-specifier
              • Reader
              • Parse-shift-expression
              • Parse-relational-expression
              • Parse-multiplicative-expression
              • Parse-logical-or-expression
              • Parse-logical-and-expression
              • Parse-inclusive-or-expression
              • Parse-exclusive-or-expression
              • Parse-equality-expression
              • Parse-enum-specifier
              • Parse-block-item-list
              • Parse-attribute-list
              • Parse-and-expression
              • Parse-additive-expression
              • Parse-abstract-declarator
              • Parse-member-designor-rest
              • Parse-declarator
              • Parse-attribute
              • Parse-type-qualifier-or-attribute-specifier
              • Parse-enumerator
              • Parse-asm-output-operand
              • Parse-asm-input-operand
        • Atc
        • Transformation-tools
        • Language
        • Representation
        • Insertion-sort
        • Pack
      • Soft
      • Bv
      • Imp-language
      • Ethereum
      • Event-macros
      • Java
      • Riscv
      • Bitcoin
      • Zcash
      • Yul
      • ACL2-programming-language
      • Prime-fields
      • Json
      • Syntheto
      • File-io-light
      • Cryptography
      • Number-theory
      • Axe
      • Lists-light
      • Builtins
      • Solidity
      • Helpers
      • Htclient
      • Typed-lists-light
      • Arithmetic-light
    • X86isa
    • Axe
    • Execloader
  • Math
  • Testing-utilities

• Parser

Parse-external-declaration

Parse an external declaration.

Signature

(parse-external-declaration parstate) 
  → 
(mv erp extdecl span new-parstate)

Arguments

parstate — Guard (parstatep parstate).

Returns

extdecl — Type (ext-declonp extdecl).

span — Type (spanp span).

new-parstate — Type (parstatep new-parstate), given (parstatep parstate).

An external declaration is either an empty one (a lone semicolon), or a function definition, which starts with a non-empty sequence of declaration specifiers, or a declaration, which also starts with a non-empty sequence of declaration specifiers, unless it is a static assert declaration, which starts with the keyword _Static_assert.

The case of an empty external declaration is easy, because it starts (and ends) with a semicolon. This is only allowed if GCC extensions are supported.

No declaration specifier starts with the keyword _Static_assert, so this keyword tells us that we must have a static assert declaration. In this case, we parse a static assert declaration.

Otherwise, we read one or more declaration specifiers, since those are present both in declarations and in function definitions. Then we must have a declarator in either case, but based on what follows it, we can decide whether we have a declarator or a function definition.

If GCC extensions are supported, we must also take into account the possible presence of attributes and assembler name specifiers, as well as of an __external__ keyword.

We also handle the GCC extension of allowing assembler statements as external declarations, which are easy to recognize.

Definitions and Theorems

Function: parse-external-declaration

(defun parse-external-declaration (parstate)
 (declare (xargs :stobjs (parstate)))
 (declare (xargs :guard (parstatep parstate)))
 (let ((__function__ 'parse-external-declaration))
  (declare (ignorable __function__))
  (b* (((reterr)
        (irr-ext-declon)
        (irr-span)
        parstate)
       ((erp token span parstate)
        (read-token parstate)))
   (cond
    ((and (token-punctuatorp token ";")
          (parstate->gcc parstate))
     (retok (ext-declon-empty)
            span parstate))
    ((token-keywordp token "_Static_assert")
     (b* (((erp statassert span parstate)
           (parse-static-assert-declaration span parstate)))
       (retok (ext-declon-declon (declon-statassert statassert))
              span parstate)))
    ((or (token-keywordp token "asm")
         (token-keywordp token "__asm")
         (token-keywordp token "__asm__"))
     (b* ((uscores (cond ((token-keywordp token "asm")
                          (keyword-uscores-none))
                         ((token-keywordp token "__asm")
                          (keyword-uscores-start))
                         ((token-keywordp token "__asm__")
                          (keyword-uscores-both))))
          ((erp asm span parstate)
           (parse-asm-statement span uscores parstate)))
       (retok (ext-declon-asm asm)
              span parstate)))
    (t
     (b* (((mv extension parstate)
           (if (token-keywordp token "__extension__")
               (mv t parstate)
             (b* ((parstate (if token (unread-token parstate)
                              parstate)))
               (mv nil parstate))))
          ((erp declspecs span parstate)
           (parse-declaration-specifiers nil parstate))
          ((erp token2 span2 parstate)
           (read-token parstate)))
      (cond
       ((token-punctuatorp token2 ";")
        (retok
         (ext-declon-declon (make-declon-declon :extension extension
                                                :specs declspecs
                                                :declors nil))
         (span-join span span2)
         parstate))
       (t
        (b* ((parstate (if token2 (unread-token parstate)
                         parstate))
             ((erp declor & parstate)
              (parse-declarator parstate))
             ((erp asmspec? & parstate)
              (parse-?-asm-name-specifier parstate))
             ((erp attrspecs & parstate)
              (parse-*-attribute-specifier parstate))
             ((erp token3 span3 parstate)
              (read-token parstate)))
         (cond
          ((token-punctuatorp token3 ";")
           (retok
            (ext-declon-declon
             (make-declon-declon
                 :extension extension
                 :specs declspecs
                 :declors (list (make-init-declor :declor declor
                                                  :asm? asmspec?
                                                  :attribs attrspecs
                                                  :initer? nil
                                                  :info nil))))
            (span-join span span3)
            parstate))
          ((token-punctuatorp token3 "=")
           (b* (((erp initer & parstate)
                 (parse-initializer parstate))
                (initdeclor (make-init-declor :declor declor
                                              :asm? asmspec?
                                              :attribs attrspecs
                                              :initer? initer
                                              :info nil))
                ((erp token4 span4 parstate)
                 (read-token parstate)))
            (cond
             ((token-punctuatorp token4 ";")
              (retok
               (ext-declon-declon
                    (make-declon-declon :extension extension
                                        :specs declspecs
                                        :declors (list initdeclor)))
               (span-join span span4)
               parstate))
             ((token-punctuatorp token4 ",")
              (b* (((erp initdeclors & parstate)
                    (parse-init-declarator-list parstate))
                   ((erp last-span parstate)
                    (read-punctuator ";" parstate)))
               (retok
                  (ext-declon-declon
                       (make-declon-declon
                            :extension extension
                            :specs declspecs
                            :declors (cons initdeclor initdeclors)))
                  (span-join span last-span)
                  parstate)))
             (t (reterr-msg
                     :where (position-to-msg (span->start span4))
                     :expected "a semicolon or a comma"
                     :found (token-to-msg token4))))))
          ((token-punctuatorp token3 ",")
           (b* ((initdeclor (make-init-declor :declor declor
                                              :asm? asmspec?
                                              :attribs attrspecs
                                              :initer? nil
                                              :info nil))
                ((erp initdeclors & parstate)
                 (parse-init-declarator-list parstate))
                ((erp last-span parstate)
                 (read-punctuator ";" parstate)))
             (retok
                  (ext-declon-declon
                       (make-declon-declon
                            :extension extension
                            :specs declspecs
                            :declors (cons initdeclor initdeclors)))
                  (span-join span last-span)
                  parstate)))
          ((token-punctuatorp token3 "{")
           (b* (((erp cstmt last-span parstate)
                 (parse-compound-statement span parstate)))
            (retok
                (ext-declon-fundef (make-fundef :extension extension
                                                :specs declspecs
                                                :declor declor
                                                :asm? asmspec?
                                                :attribs attrspecs
                                                :declons nil
                                                :body cstmt
                                                :info nil))
                (span-join span last-span)
                parstate)))
          (t
           (b*
            ((parstate (if token3 (unread-token parstate)
                         parstate))
             ((erp decls & parstate)
              (parse-declaration-list parstate))
             ((erp open-curly-span parstate)
              (read-punctuator "{" parstate))
             ((erp cstmt last-span parstate)
              (parse-compound-statement open-curly-span parstate)))
            (retok
                (ext-declon-fundef (make-fundef :extension extension
                                                :specs declspecs
                                                :declor declor
                                                :asm? asmspec?
                                                :attribs attrspecs
                                                :declons decls
                                                :body cstmt
                                                :info nil))
                (span-join span last-span)
                parstate)))))))))))))

Theorem: ext-declonp-of-parse-external-declaration.extdecl

(defthm ext-declonp-of-parse-external-declaration.extdecl
  (b* (((mv acl2::?erp ?extdecl ?span ?new-parstate)
        (parse-external-declaration parstate)))
    (ext-declonp extdecl))
  :rule-classes :rewrite)

Theorem: spanp-of-parse-external-declaration.span

(defthm spanp-of-parse-external-declaration.span
  (b* (((mv acl2::?erp ?extdecl ?span ?new-parstate)
        (parse-external-declaration parstate)))
    (spanp span))
  :rule-classes :rewrite)

Theorem: parstatep-of-parse-external-declaration.new-parstate

(defthm parstatep-of-parse-external-declaration.new-parstate
  (implies (parstatep parstate)
           (b* (((mv acl2::?erp ?extdecl ?span ?new-parstate)
                 (parse-external-declaration parstate)))
             (parstatep new-parstate)))
  :rule-classes :rewrite)

Theorem: parsize-of-parse-external-declaration-uncond

(defthm parsize-of-parse-external-declaration-uncond
  (b* (((mv acl2::?erp ?extdecl ?span ?new-parstate)
        (parse-external-declaration parstate)))
    (<= (parsize new-parstate)
        (parsize parstate)))
  :rule-classes :linear)

Theorem: parsize-of-parse-external-declaration-cond

(defthm parsize-of-parse-external-declaration-cond
  (b* (((mv acl2::?erp ?extdecl ?span ?new-parstate)
        (parse-external-declaration parstate)))
    (implies (not erp)
             (<= (parsize new-parstate)
                 (1- (parsize parstate)))))
  :rule-classes :linear)